import mx.transitions.Tween;

var fadeTijd:Number = 3;//seconden dat de fade erover doet om van 0 tot 100 te gaan
var holdTijd:Number = 3;//seconden dat het plaatje blijft staan NA ingefade te zijn

//de in te laden images
var fotoArray:Array = new Array("plaatje_een.jpg",
                "plaatje_twee.jpg",
                "plaatje_drie.jpg"
                //etc
                );

//vars (types) declareren
var aantal:Number = fotoArray.length;
var i:Number = 0;
var a:Number = 0;

//mcs bakken, twee stuks om in elkaar te faden
var lader1:MovieClip = createEmptyMovieClip("lader1",this.getNextHighestDepth());
var lader2:MovieClip = createEmptyMovieClip("lader2",this.getNextHighestDepth());

//alpha op 0 zetten :p
lader1._alpha = 0;
lader2._alpha = 0;


function fadeIN() {
  // i resetten als hij groter is dan het aantal images in het array (of evt xml)
  if(i >= aantal){
    i=0;
  }
 
  //kiezen tussen lader 1 of 2
  if (a%2 == 0) {
    //top positie bepalen/setten
    if(lader1.getDepth() < lader2.getDepth() ){
      lader1.swapDepths(lader2)
    }
    //foto inladen in lader1
    lader1.loadMovie(fotoArray[i]);
    //de alpha tweenen
    var inEEN:Tween = new Tween(lader1, "_alpha", linear, 0, 100, fadeTijd, true);
    //"oude" img uit tweenen
    var uitTWEE:Tween = new Tween(lader2, "_alpha", linear, 100, 0, fadeTijd, true);

  } else {
    //top positie bepalen/setten
    if(lader2.getDepth() < lader1.getDepth() ){
      lader2.swapDepths(lader1)
    }
    //foto inladen in lader2
    lader2.loadMovie(fotoArray[i]);
    //de alpha in tweenen
    var inTWEE:Tween = new Tween(lader2, "_alpha", linear, 0, 100, fadeTijd, true);
    //"oude" image uit tweenen
    var uitEEN:Tween = new Tween(lader1, "_alpha", linear, 100, 0, fadeTijd, true);
  }
 
  i++; //array index ophogen
  a++; //ophogen om te bepalen wat de volgende mc word die moet laden/faden
}

//de eerste keer aanroepen, anders duurt het X tijd voordat je eerste img getoond word
fadeIN();

//timer die de functie aanroept
var gaanMetDieBanaan:Number = setInterval(fadeIN, (fadeTijd*1000)+(holdTijd*1000)); 
 

/*
Alleen de paden naar de foto's in het array aanpassen en eventueel de fade snelheid en de tijd dat de images in beeld moeten blijven staan na het faden.
*/